Kształty Jąder Atomowych

Wizualizacja kształtów używanych do opisu zdeformowanych jąder atomowych

Wprowadzenie

Wiele zjawisk zachodzących w jądrach atomowych sugeruje, że są one zdeformowane. 
Choć kształt jądra nie jest obserwablą kwantową, to pojęcie to jest bardzo pomocne w 
opisie i zrozumieniu budowy jąder.

W zależności od badanego problemu stosuje się różne parametryzacje kształtu. 
Często stosuje się rozwinięcie w szereg funkcji (harmonik) sferycznych. 
Tu przyjmiemy tę metodę, ale rozważymy też parametryzację stosowaną 
w modelu Nilssona, o którym będzie mowa w jednym z późniejszych wykładów.

Rozwinięcie na harmoniki sferyczne

Opis powierzchni

Promień wodzący opisujący powierzchnię sferoidalnego kszałtu:

R(θ, ϕ) =c(α) (Subscript[R, 0  ])[1+(∑_(λ=2)^(Subscript[λ, max]))(∑_(μ=-λ)^λ)(Subscript[a, λμ]) (Subscript[Y, λμ]) (θ,ϕ)].

(Subscript[R, 0]) to średni promień,  c(α) to czynnik, który normalizuje objętość kształtu.

Harmoniki sferyczne

Funkcje Y to dobrze znane (elektrodynamika, kwanty) harmoniki sferyczne.
Ich ogólna definicja:

(Subscript[Y, l,m])= (Sqrt[(((2l+1))/(4 π )) (((l-m)!)/((l+m)!)) ])(Subscript[P, l,m]) (cosθ) (e^(i m ϕ)) ,

gdzie  (Subscript[P, l,m]) (cosθ) to tzw. stowarzyszone wielomiany Legendre’a.

Funkcje kwadrupolowe

Najczęściej będziemy używać funkcji kwadrupolowych, czyli dla λ=2 :

(Subscript[Y, 2,0 ])=(1/2) (Sqrt[(5/(4π))]) (3 (cos^2)(θ)-1)

(Subscript[Y, 2,-1 ])=(1/2) (Sqrt[(15/(2π))]) sin(θ) cos(θ) (e^(-iϕ)),   (Subscript[Y, 2,1 ])=-(1/2) (Sqrt[(15/(2π))]) sin(θ) cos(θ) (e^(iϕ))

(Subscript[Y, 2,-2 ])=(1/2) (Sqrt[(15/(4π))]) (sin^2)(θ) (e^(-2iϕ)),   (Subscript[Y, 2,2 ])=(1/2) (Sqrt[(15/(2π))]) (sin^2)(θ) (e^(2iϕ))

Promień nieurojony

Ponieważ promień musi  być liczbą rzeczywistą, to współczynniki deformacji :

(Subscript[a, λμ])=(((-1))^μ)(Subscript[a, λ,-μ]) .

Gdy kształt jest osiowo symetryczny, to znikają wszystkie współczynniki deformacji dla μ≠0.

Dla pozostałych współczynników stosuje się wtedy oznaczenie: (Subscript[a, λ0])≡ (Subscript[β, λ]) .

Harmoniki w Mathematica

Mathematica oczywiście "zna" harmoniki sferyczne, więc zawsze można sprawdzić postać   konkretnej funkcji :

SphericalHarmonicY[2,-1,θ,ϕ]

SphericalHarmonicY[2,0,θ,ϕ]

Definicje przydatnych funkcji

Aby skrócić pisanie, na użytek tego wykładu definiujemy skrót:

Y[l_,m_]:=SphericalHarmonicY[l,m,θ,φ]

Y[2,0]

Wykres funkcji r(θ) w 2D:

pplot2D[r_] := ParametricPlot[{Sin[θ]r,Cos[θ]r},{θ,0,2Pi},
PlotRange -> {{-2, 2}, {-2, 2}},
     AxesLabel->{x,z},
AxesStyle->Directive[Thick,Black,18],
PlotStyle->{Blue,Thickness[0.008]} ,
ImageSize->500                       
                            ]

Wykres funkcji r(θ,φ)  w 3D :

pplot3D[r_] := ParametricPlot3D[{Cos[φ]Sin[θ]r,Sin[φ]Sin[θ]r,Cos[θ]r},
     {θ,0,Pi},{φ,0,2Pi},
AxesStyle->Directive[Thick,Black,16],
AxesLabel->{Style[x, Large,Bold],
Style[y, Large,Bold],
Style[z, Large,Bold]},
PlotPoints->20,
Mesh->Full,
ImageSize->{400,400}]

Kształty osiowo symetryczne w 2 D

Pouczające bywa spojrzenie na dwuwymiarowe projekcje kształtów sferoidalnych, szczególnie przy zachowaniu symetrii osiowej (m=0). Pomijamy po prostu kąt ϕ  i rysujemy harmoniki w płaszczyźnie (x,z). Kształt trójwymiarowy powstaje przez obrót rysunku wokół osi z .

pplot2D[1+0.6Y[2,0]]

Manipulacja 1: (Subscript[β, 2])

Wprowadźmy możliwość interakcyjnej zmiany deformacji:

Manipulate[
Module[{r},
r=1+beta2*Y[2,0];
pplot2D[r]],
(* Kontrolki *)
{{beta2,0,Style["Deformacja (Subscript[β, 2])",22]},-1.5,1.5,0.05, Appearance->"Labeled", LabelStyle->Directive[Red,22]},
FrameLabel->{None,None, Style["R = 1 + (Subscript[β, 2])*(Subscript[Y, 20])",Blue,22], None},
SaveDefinitions->True
]

Manipulacja 2: l, (Subscript[β, l])

Dodajemy możliwość wyboru multipolowości:

Manipulate[Module[{r},
r=1+betal*Y[mul,0];
pplot2D[r]],
(* Kontrolki *)
{{mul,2,Style["Multipolowość l",22]},Range[1,6], ControlType->RadioButton},
{{betal,0,Style["Deformacja (Subscript[β, l])",22]},-1.5,1.5,0.05, Appearance->"Labeled", LabelStyle->Directive[Red,22]},
FrameLabel->{None, None, Style["R = 1 + (Subscript[β, l])*(Subscript[Y, l0])",Blue,22], None},
SaveDefinitions->True
]

Kształty kwadrupolowe

Pierwszym krokiem w opisie kształtu jąder atomowych jest przyjęcie deformacji kwadrupolowej. Dlatego z tą deformacją mamy najczęściej do czynienia.

W ogólnym przypadku (już nie zakładamy symetrii osiowej!) i w układzie własnym jądra dwa współczynniki całkowicie określają kształt kwadrupolowy.

Przyjęto następującą konwencję:

(Subscript[a, 20])=β cosγ ,
(Subscript[a, 22])=(Subscript[a, 2-2])=(1/(Sqrt[2]))β sinγ ,
(Subscript[a, 21])=(Subscript[a, 2-1])=0 .

Gdy γ=0, mamy kształt o symetrii osiowej: (Subscript[a, 20])=β , (Subscript[a, 22])=0 .

Promień wodzący jako funkcja β i γ :

r22=1+β*Cos[γ]*Y[2,0]+β*Sin[γ]/Sqrt[2]*(Y[2,2]+Y[2,-2])

r22=Simplify[ExpToTrig[r22]]

rkwad=r22/.{β->0.4,γ->30 Degree};
pplot3D[rkwad]

Manipulacja 3: β,γ

Badamy wpływ parametrów β i γ :

Manipulate[Module[{a20,a22,r2},
a20=bet Cos[gam Degree];
a22=bet Sin[gam Degree]/Sqrt[2];
r2=1+a20*Y[2,0]+a22(Y[2,2]+Y[2,-2]);
pplot3D[r2]],
{{bet,0,Style["Deformacja β",22]},-0.8,0.8,0.05, Appearance->"Labeled", LabelStyle->Directive[Red,22]},
{{gam,0,Style["Deformacja γ",22]},0,60,5., Appearance->"Labeled", LabelStyle->Directive[Red,22]},
FrameLabel->{{None,None},{None ,Style["Ogólny kszałt kwadrupolowy",Blue,22]}},
SaveDefinitions->True
]

Manipulacja 4: β, γ, stała objętość

Możemy jeszcze zapewnić stałą objętość.  
Objętość sferoidy jest proporcjonalna do iloczynu półosi głównych. 
W naszym przypadku:

(Subscript[R, x])=R(θ=π/2, φ=0),
(Subscript[R, y])=R(θ=π/2, φ=π/2),
(Subscript[R, z])=R(θ=0, φ=0)

Manipulate[Module[{a20,a22,r2,rx,ry,rz},
a20=bet Cos[gam Degree];
a22=bet Sin[gam Degree]/Sqrt[2];
r2=1+a20*Y[2,0]+a22(Y[2,2]+Y[2,-2]);
rx=r2/.{θ->Pi/2,φ->0};
ry=r2/.{θ->Pi/2,φ->Pi/2};
rz=r2/.{θ->0,φ->0};
r2=r2/(rx*ry*rz);
pplot3D[r2]],
{{bet,0,Style["Deformacja β",22]},-0.8,0.8,0.05, Appearance->"Labeled", LabelStyle->Directive[Red,22]},
{{gam,0,Style["Deformacja γ",22]},0,60,5., Appearance->"Labeled", LabelStyle->Directive[Red,22]},
FrameLabel->{{None,None},{None ,Style["Ogólny kszałt kwadrupolowy (stała objętość)",Blue,22]}},
SaveDefinitions->True
]

Manipulacja 5: interaktywna mapa β,γ

W poprzednich manipulacjach γ zmieniało się od 0 do 60 stopni, bo to wystarcza do opisu wszystkich kształtów. Chcemy teraz teraz to zobaczyć.

W pierwszym kroku tworzymy interaktywną mapę przestrzeni β,γ pozwalającą na wybór tych parametrów.

plcircles=PolarPlot[{0.2,0.4,0.6,0.8,1.0},{t,0,2 Pi},
PlotStyle->Directive[Blue,Thin],
PlotRange->{{-1.15,1.15},{-1.25,1.15}},
ImageSize->400,
Axes->None];

plline1=Graphics[{Thin, Brown,
Line[{{-1.1,0},{1.1,0}}],Text[Style["γ=0",16],{1.2,0.07},Right]}];
plline2=Graphics[{Thin, Brown,
Line[{{-1.1*Cos[Pi/3],-1.1*Sin[Pi/3]},{1.1*Cos[Pi/3],1.1*Sin[Pi/3]}}],Text[Style["γ=60",16],{1.1*Cos[Pi/3]+0.25,1.05*Sin[Pi/3]},Right]}];
plline3=Graphics[{Thin, Brown,
Line[{{-1.1*Cos[2 Pi/3],-1.1*Sin[2Pi/3]},{1.1*Cos[2Pi/3],1.1*Sin[2Pi/3]}}],Text[Style["γ=120",16],{1.1*Cos[2Pi/3]+0.25,1.18*Sin[2Pi/3]},Right]}];

Manipulate[Module[{bet,gam},
bet=NumberForm[Setting[Dynamic[First[ToPolarCoordinates[pt]]]],2];
gam=NumberForm[Setting[Dynamic[Last[ToPolarCoordinates[pt]]/Degree]],2];
Grid[{{
LocatorPane[
Dynamic[pt],
Show[{plcircles,plline1,plline2,plline3},
ImagePadding->{{0,0},{0,0}},
Epilog->{Red,Point[Dynamic[pt]],
Text[Style[StringForm["β = `1`",bet],Red,20],{-0.5,-1.2}],
Text[Style[StringForm["γ = `1`",gam],Red,20],{0.5,-1.2}]
}]
]
}},
ItemSize->All]],
{{pt,{0.1,0}},None},
FrameLabel->{{None,None},{None ,Style["Mapa przestrzeni β, γ",Blue,24]}},
SaveDefinitions->True
]

Manipulacja 6:  kształty w przestrzeni β i γ

Łączymy teraz manipulację 3 i 5, czyli rysujemy ogólny kształt kwadrupolowy (bez stałej objętości) dla wybranych parametrów β,γ .

Manipulate[Module[{bet,gam,a20,a22,r2},
bet=NumberForm[Setting[Dynamic[First[ToPolarCoordinates[pt]]]],2];
gam=NumberForm[Setting[Dynamic[Last[ToPolarCoordinates[pt]]/Degree]],2];
a20=Setting[Dynamic[First[ToPolarCoordinates[pt]]*
 Cos[Last[ToPolarCoordinates[pt]]]]];
a22=Setting[Dynamic[First[ToPolarCoordinates[pt]]*
 Sin[Last[ToPolarCoordinates[pt]]]/Sqrt[2]]];
r2=1+a20*Y[2,0]+a22*(Y[2,2]+Y[2,-2]);
Grid[{{
LocatorPane[
Dynamic[pt],
Show[{plcircles,plline1,plline2,plline3},
ImagePadding->{{0,0},{0,0}},
Epilog->{Red,Point[Dynamic[pt]],
Text[Style[StringForm["β = `1`",bet],Red,20],{-0.5,-1.2}],
Text[Style[StringForm["γ = `1`",gam],Red,20],{0.5,-1.2}]
}]
],
pplot3D[r2]
}},
ItemSize->All]],
{{pt,{0.1,0}},None},
FrameLabel->{{None,None},{None ,Style["Ogólny kszałt kwadrupolowy w pełnej przestrzeni β, γ",Blue,24]}},
SaveDefinitions->True
]

Deformacja kwadrupolowa w modelu Nilssona

Model Nilssona bazuje na potencjale oscylatora harmonicznego. Deformację wprowadza się tu inaczej, rozważając oscylator harmoniczny anizotropowy.

Wiadomo, że częstość oscylatora jest odwrotnie proporcjonalna do promienia jądra:

ℏω≈((41 MeV)/(A^(1/3)))∼(1/R).

Gdy zmieniamy rozmiar jądra wzdłuż jednej z osi, zmieniamy też częstość drgań w kierunku tej osi:

(Subscript[ω, x])=(Subscript[ω, 0]) ((Subscript[R, 0])/(Subscript[a, x])),  (Subscript[ω, y])=(Subscript[ω, 0]) ((Subscript[R, 0])/(Subscript[a, y])),  (Subscript[ω, z])=(Subscript[ω, 0]) ((Subscript[R, 0])/(Subscript[a, z])) .

Warunek stałej objętości prowadzi do:

(Subscript[ω, x])(Subscript[ω, y])(Subscript[ω, z])=(Subscript[ω, 0]^3) ((Subscript[R, 0]^3)/((Subscript[a, x])(Subscript[a, y])(Subscript[a, z])))=(Subscript[ω, 0]^3) .

Symetria osiowa

W przypadku symetrii osiowej przyjmuje się zwyczajowo, że osią symetrii jest z.

Parametr deformacji w modelu Nilssona, δ :

(Subscript[ω, x])=(Subscript[ω, y])=(Subscript[ω, 0])(δ)(1+(1/3)δ),    (Subscript[ω, z])=(Subscript[ω, 0])(δ)(1-(2/3)δ).

ωxyz=Expand[(1+δ/3)*(1+δ/3)*(1-2*δ/3)]

Półosie elipsoidy dane są przez:

(Subscript[a, x])=(Subscript[a, y])=(Subscript[ω, 0])(Subscript[R, 0])/(Subscript[ω, x]) ,  (Subscript[a, z])=(Subscript[ω, 0])(Subscript[R, 0])/(Subscript[ω, z ]) .

W jednostkach (Subscript[R, 0]) wynoszą więc:

((Subscript[a, x])/(Subscript[R, 0]))=((Subscript[a, y])/(Subscript[R, 0]))=((((1-(δ^2)/3-2 (δ^3)/27))^(1/3))/(1+δ/3)) ,  ((Subscript[a, z])/(Subscript[R, 0]))=((((1-(δ^2)/3-2 (δ^3)/27))^(1/3))/(1-2δ/3)) .

Możemy porównać parametr deformacji δ z wprowadzonym poprzednio parametrem β.

Promień zapisany przez harmoniki dla symetrii osiowej:

r22 /.{γ->0}

Długość półosi z dostajemy kładąc θ=0:

rzharm=r22 /.{γ->0,θ->0}

Półoś z Nilssona :

rzN=((((1-(δ^2)/3-2 (δ^3)/27))^(1/3))/(1-2δ/3))

Widać, że w przybliżeniu (dla małych deformacji):

(Subscript[r, N])≈1+(2/3)δ≈1+(1/2)(Sqrt[(5/π)])β=(Subscript[r, harm]) ,

czyli

δ≈(3/4)(Sqrt[(5/π)])β , lub  β≈(4/3)(Sqrt[(π/5)])δ .

Ale możemy to zrobić lepiej!

Wyznaczamy β jako funkcję δ:

Solve[rzharm==rzN, β]

Flatten[%]

beta=Flatten[Solve[rzharm==rzN, β]][[1,2]]

Przedstawiamy wynik jako szereg potęgowy względem δ

betaapprox=Series[beta,{δ,0,4}]

Manipulacja 7: elipsoida osiowa Nilssona

Przypominamy długości półosi elipsoidy Nilssona:

((Subscript[a, x])/(Subscript[R, 0]))=((Subscript[a, y])/(Subscript[R, 0]))=((((1-(δ^2)/3-2 (δ^3)/27))^(1/3))/(1+δ/3)) ,  ((Subscript[a, z])/(Subscript[R, 0]))=((((1-(δ^2)/3-2 (δ^3)/27))^(1/3))/(1-2δ/3)) .

Zbadamy kształt elipsoidy w zależności od δ . Przy okazji wyświetlamy stosunek częstości wzdłuż osi z i osi prostopadłych oraz wartość parametru β odpowiadającą δ.

Uwaga, teraz zadajemy kształt podając 3 składowe każdego punktu, a nie poprzez promień wodzący, który jest funkcją θ i φ. Dlatego nie możemy skorzystać ze skrótu pplot3D.

Manipulate[Module[{omega,po,pz,beta},
omega=(1-delta^2/3-2*delta^3/27)^(1/3);
po = omega/(1+delta/3);
pz =omega/(1-2 * delta/3);
beta=(4/3) (Sqrt[(π/5)]) delta+(2/3) (Sqrt[(π/5)]) (delta^2);
ParametricPlot3D[{Cos[φ]Sin[θ]*po,Sin[φ]Sin[θ]*po,Cos[θ] *pz},{θ,0,Pi},{φ,0,2Pi},
     PlotRange -> {{-1.3, 1.3}, {-1.3, 1.3}, {-1.5, 1.5}},
AxesStyle->Directive[Thick,Black,16],
AxesLabel->{Style[x, Large,Bold],
Style[y, Large,Bold],
Style[z, Large,Bold]},
PlotPoints->20,
Mesh->Full,
ImageSize->{500,500},
     Axes -> True, 
FaceGrids->None,
PlotLabel->Row[{
Style["(Subscript[ω, ⊥])/(Subscript[ω, z]) = ",Brown,FontSize->22],
Style[NumberForm[pz/po,2],Brown,FontSize->22],
Style["   β = ",Brown,FontSize->22],
Style[NumberForm[beta,2],Brown,FontSize->22]}]]] ,
{{delta,0,Style["Deformacja δ",22]},-1,1,0.2,Appearance->"Labeled",LabelStyle->Directive[Red,22]},
FrameLabel->{{None,None},{None ,Style["Elipsoida Nilssona (stała objętość)",Blue,24]}}
]

Jądro trójosiowe w modelu Nilssona

W przypadku deformacji trójosiowej, częstości wzdłuż trzech osi zapisuje się:

(Subscript[ω, x])=(Subscript[ω, 0])(δ,γ)(1-(2/3)δ cos(γ+2π/3)),  
(Subscript[ω, y])=(Subscript[ω, 0])(δ,γ)(1-(2/3)δ cos(γ-2π/3)),
  (Subscript[ω, z])=(Subscript[ω, 0])(δ,γ)(1-(2/3)δ cosγ),

gdzie parametr γ opisuje odstępstwo od symetrii osiowej. Jest to ten sam parametr, co używany przy opisie harmonicznym.

Długości półosi są teraz, jak poprzednio :

((Subscript[a, x])/(Subscript[R, 0]))=(((((Subscript[ω, x])(Subscript[ω, y])(Subscript[ω, z])))^(1/3))/(Subscript[ω, x])) ,  
((Subscript[a, y])/(Subscript[R, 0]))=(((((Subscript[ω, x])(Subscript[ω, y])(Subscript[ω, z])))^(1/3))/(Subscript[ω, y])) ,
((Subscript[a, z])/(Subscript[R, 0]))=(((((Subscript[ω, x])(Subscript[ω, y])(Subscript[ω, z])))^(1/3))/(Subscript[ω, z])) .

Manipulacja 8: półosie w modelu Nilssona

Zobaczmy jak te długości zależą od δ i γ :

line60deg=Graphics[{Thin, Brown,Line[{{60,0},{60,2}}]}];
Manipulate[Module[{plotN3},
plotN3=Plot[{1-2*delta*Cos[x*Pi/180+2*Pi/3]/3,
1-2*delta*Cos[x*Pi/180-2*Pi/3]/3,
1-2*delta*Cos[x*Pi/180]/3},
{x,-180,180},
PlotRange->{{-180,180},{0,2}},
AxesLabel->{"γ [deg]"," "},
PlotLabel->Row[{
Style["(Subscript[ω, x]) ",Red,FontSize->22],
Style[" (Subscript[ω, y]) ",Blue,FontSize->22],
Style[" (Subscript[ω, z]) ",Darker[Green],FontSize->22]
}], 
AxesStyle->Directive[Thick,Black,20],
PlotStyle->{{Red,Thickness[0.008]},
{Blue,Thickness[0.008]},
{Darker[Green],Thickness[0.008]}},
ImageSize->600];
Show[{plotN3,line60deg}]], 
{{delta,0,Style["Deformacja δ",22]},-1.2,1.2,0.05,Appearance->"Labeled", LabelStyle->Directive[Red,22]},
FrameLabel->{{None,None},{None ,Style["Półosie kształtu Nilssona",Blue,24]}},
SaveDefinitions->True
]

Manipulacja 9: trójosiowe jądro Nilssona

Mając półosie, możemy narysować kształt jądra trójosiowego w modelu Nilssona.

Manipulate[Module[{gamma,px,py,pz,V},
gamma=ang*Pi/180;
px = 1/(1-2*delta*Cos[gamma+2*Pi/3]/3);
py=1/(1-2*delta*Cos[gamma-2*Pi/3]/3);
pz =1/(1-2 * delta*Cos[gamma]/3);
V=(px*py*pz)^(1/3);
ParametricPlot3D[{Cos[φ]Sin[θ]*px/V,Sin[φ]Sin[θ]*py/V,Cos[θ] *pz/V},{θ,0,Pi},{φ,0,2Pi},
     PlotRange -> {{-1.3, 1.3}, {-1.3, 1.3}, {-1.5, 1.5}},
     Axes -> True, 
AxesStyle->Directive[Thick,Black,16],
AxesLabel->{Style["x", Large,Bold],
Style["y", Large,Bold],
Style["z", Large,Bold]},
PlotPoints->20,
Mesh->Full,
ImageSize->{500,500},
FaceGrids->None,
PlotLabel->Column[
{Row[{Style["(Subscript[a, x]) = ",Red,FontSize->22],
       Style[NumberForm[px/V,3],Red, FontSize->22]}],
Row[{Style["(Subscript[a, y]) = ",Blue,FontSize->22],
       Style[NumberForm[py/V,3],Blue,FontSize->22]}],
Row[{Style["(Subscript[a, z]) = ",Darker[Green],FontSize->22],
      Style[NumberForm[pz/V,3],Darker[Green],FontSize->20]}]} ],
ImageSize->500]],
{{delta,0,Style["Deformacja δ",22]},0,1,0.1,Appearance->"Labeled",LabelStyle->Directive[Red,22]},
{{ang,0,Style["Parametr γ [deg]",22]},0,60,0.5,Appearance->"Labeled",LabelStyle->Directive[Red,22]},
FrameLabel->{{None,None},{None ,Style["Trójosiowe jądro Nilssona",Blue,24]}},
SaveDefinitions->True
]

Deformacje wyższych rzędów

W fizyce jądrowej duże znaczenie mają też deformacje wyższych rzędów, szczególnie oktupolowe (l=3) i heksadekapolowe (l=4).

Jednak rzadko odchodzi się od symetrii osiowej.

Omówimy jeden interesujący przykład i bardziej rozbudowane narzędzie do wizualizacji kształtów opisanych przez wszystkie multipole od 1 do 4.

Kanciate jądra?

W 2002 roku w Phys. Rev. Lett. ukazała się praca Jerzego Dudka i in., w której autorzy przewidują możliwość istnienia jąder o kształcie tetrahedralnym (czworościanu foremnego). Praca wzbudziła spore zainteresowanie. Dotychczas nie udało się jednak znaleźć przekonujących świadectw doświadczalnych na poparcie tej hipotezy.

↦ J. Dudek et al., Phys. Rev. Lett. 88, 252502 (2002)

Kwadratura jądra

Idea czworościennych jąder odbiła się echem także w prasie codziennej. 
Pisała o tym np. Gazeta Wyborcza:

Manipulacja 10: wizualizacja bogatszych kształtów

Nowe kształty sugerowane w pracy J. Dudka wymagały dodania wyrazów (Subscript[Y, 31]) i (Subscript[Y, 32]), zawsze dotąd pomijanych (nieosiowy oktupol).

Na koniec zobaczmy więc jaki wpływ na kształt jądra mają deformacje oktupolowe (l = 3) i heksadekapolowe (l = 4).

Wracamy do rozwinięcia na harmoniki sferyczne i rysujemy dowolny kształt dla l=2,3,4.

Manipulate[
Module[{r2,r3,r4,rn},
r2=a20 Y[2,0]+a22(Y[2,2]+Y[2,-2]);
r3=a30 Y[3,0]+a31 (Y[3,1]-Y[3,-1])+a32 (Y[3,2]+Y[3,-2])+a33 (Y[3,3]-Y[3,-3]);
r4=a40 Y[4,0]+a41 (Y[4,1]-Y[4,-1])+a42 (Y[4,2]+Y[4,-2])+a43(Y[4,3]-Y[4,-3])+a44(Y[4,4]+Y[4,-4]);
rn=1+r2+r3+r4;
ParametricPlot3D[{Cos[φ]Sin[θ]rn,Sin[φ]Sin[θ]rn,Cos[θ]rn},{θ,0,Pi},{φ,0,2Pi},Axes->False,AspectRatio->Automatic,ImageSize->{400,500},ViewPoint->{2.6,-4.8,2.0}]],
{{a20,0,Style["a20",20]},0,1,0.1,Appearance->"Labeled",LabelStyle->Directive[Black,20]},
{{a22,0,Style["a22",20]},0,1,0.1,Appearance->"Labeled",LabelStyle->Directive[Black,20]},
Delimiter,
{{a30,0,Style["a30",20]},0,1,0.1,Appearance->"Labeled",LabelStyle->Directive[Black,20]},
{{a31,0,Style["a31",20]},0,1,0.1,Appearance->"Labeled",LabelStyle->Directive[Black,20]},
{{a32,0,Style["a32",20]},0,1,0.1,Appearance->"Labeled",LabelStyle->Directive[Black,20]},
{{a33,0,Style["a33",20]},0,1,0.1,Appearance->"Labeled",LabelStyle->Directive[Black,20]},
Delimiter,
{{a40,0,Style["a40",20]},0,1,0.1,Appearance->"Labeled",LabelStyle->Directive[Black,20]},
{{a41,0,Style["a41",20]},0,1,0.1,Appearance->"Labeled",LabelStyle->Directive[Black,20]},
{{a42,0,Style["a42",20]},0,1,0.1,Appearance->"Labeled",LabelStyle->Directive[Black,20]},
{{a43,0,Style["a43",20]},0,1,0.1,Appearance->"Labeled",LabelStyle->Directive[Black,20]},
{{a44,0,Style["a44",20]},0,1,0.1,Appearance->"Labeled",LabelStyle->Directive[Black,20]},
ControlPlacement->Left,
TrackedSymbols->{a20,a22,a30,a31,a32,a33,a40,a41,a42,a43,a44},
FrameLabel->{None, None,fulltitle,None},
AppearanceElements->None,
SaveDefinitions->True,
Initialization:>(
title1=Graphics[Text[Style["Harmoniczne kształty jądra - kropli cieczy",Black,Bold,FontFamily->"Verdana",22]]];
title2=Graphics[Text[Style["R(Ω) ∼ 1 + (∑_(λ = 2)^4)(∑_(μ = -λ)^λ)\!\(\*SubscriptBox[\(a\), \(\(λμ\)\(\\ \)\)]\)(Subscript[Y, λμ])(Ω),  \!\(\*SubscriptBox[\(a\), \(\(λ\)\(\\ \)\(-\)\(μ\)\(\\ \)\)]\)= (-1)^μ (Subscript[a, λμ])",Blue,FontFamily->"Georgia",22]]];
fulltitle=GraphicsColumn[{title1,title2},AspectRatio->0.18,ImageSize->600,Frame->True];
Y[l_,m_]:=SphericalHarmonicY[l,m,θ,φ])
]