Efekty sił resztkowych

Konfiguracje dwóch nukleonów, siły δ, mieszanie stanów

Dwa nukleony poza zamkniętą powłoką

Wyznaczenie stanów jednocząstkowych modelu powłokowego pozwala zrozumieć pojawianie się liczb magicznych, a także interpretować stany podstawowe i nisko leżące stany wzbudzone tylko dla małej liczby jąder leżących blisko jąder (podwójnie)magicznych. Gdy poza zamkniętą powłoką występuje więcej nukleonów, w grę wchodzą oddziaływania resztkowe, czyli te, które nie są uwzględnione w polu (potencjale) średnim.

W obliczeniach struktury jądra stosuje się kilka metod opisu sił resztkowych. Ważną rolę odgrywają tzw. oddziaływania schematyczne, a wśród nich najprostszym i dogodnym do celów dydaktycznych jest oddziaływanie typu δ. Zakłada ono, że energia oddziaływania między dwoma nukleonami walencyjnymi jest:

(Subscript[V, 12])(δ)=-(Subscript[V, 0]) δ((OverVector[(Subscript[r, 1])]) - (OverVector[(Subscript[r, 2])])).

Przyjmując oddziaływanie δ zobaczymy jak wpływa to na możliwe stany dwóch nukleonów poza zamkniętą powłoką.

Konfiguracje dwucząstkowe z siłami δ

Zagadnienie to jest dość dokładnie opisane w książce R. Castena “Nuclear Structure from a Simple Perspective” (Oxford 2000). Idziemy tu jego śladami.

Układ dwóch nukleonów na orbitalach (Subscript[j, 1 ]), (Subscript[j, 2]) może utworzyć kilka stanów o różnym całkowitym momencie pędu J. Gdyby nie było oddziaływań resztkowych, wszystkie te stany miałyby tę samą energię (degeneracja) równą (Subscript[E, 0])+(Subscript[ϵ, 1])+(Subscript[ϵ, 2]), gdzie (Subscript[E, 0]) to energia rdzenia, a (Subscript[ϵ, i]) to energia stanu jednocząstkowego. Siły resztkowe znoszą tę degenerację. W pierwszym przybliżeniu zmiana energii stanu, względem tej energii niezaburzonej wynosi:

ΔE((Subscript[j, 1]),(Subscript[j, 2]), J)=⟨(Subscript[j, 1])(Subscript[j, 2]),J|-(Subscript[V, 0]) δ((OverVector[(Subscript[r, 1])])-(OverVector[(Subscript[r, 2])]))|(Subscript[j, 1])(Subscript[j, 2]),J⟩.

Okazuje się, że te elementy macierzowe można przedstawić w postaci:

ΔE((Subscript[j, 1]),(Subscript[j, 2]), J)=-(Subscript[V, 0])(Subscript[F, 0])((Subscript[n, 1])(Subscript[l, 1])(Subscript[n, 2])(Subscript[l, 2])) ×A((Subscript[j, 1])(Subscript[j, 2])J),

gdzie A((Subscript[j, 1])(Subscript[j, 2])J) jest całką kątową, która decyduje o względnym położeniu stanów, a (Subscript[F, 0]) jest całką radialną, która nie zależy od J.

Takie same nukleony (n-n lub p-p)

Mamy wówczas:

(Subscript[F, 0])((Subscript[n, 1])(Subscript[l, 1])(Subscript[n, 2])(Subscript[l, 2]))=(1/(4π))∫(1/(r^2))(Subscript[R, (Subscript[n, 1])(Subscript[l, 1])]^2)(r) (Subscript[R, (Subscript[n, 2])(Subscript[l, 2])]^2)(r)dr,

Dwa takie same nukleony mają izospin T=1 (f. symetryczna), co oznacza, że część przestrzenno-spinowa musi być antysymetryczna. Rozważamy 2 przypadki.

Takie same orbity ((Subscript[j, 1])=(Subscript[j, 2])):

Wtedy całkowity moment pędu J może być tylko parzysty, co wynika z symetrii współczynników Clebscha-Gordana. Całka kątowa wynosi wtedy:

A(j j J)=(1/2)((((2j+1))^2)/(2J+1))((⟨j(1/2),j-(1/2),J0⟩)^2), J tylko parzyste.

Różne orbity ((Subscript[j, 1])≠(Subscript[j, 2])):

Wartość J może być parzysta lub nieparzysta, a całka kątowa jest:

A((Subscript[j, 1])(Subscript[j, 2])J)=(1/2) (((2(Subscript[j, 1])+1)(2(Subscript[j, 2])+1))/(2J+1)) ((⟨(Subscript[j, 1])(1/2),(Subscript[j, 2])-(1/2),J0⟩)^2)(1+(((-1))^((Subscript[l, 1])+(Subscript[l, 2])+J))).

Zauważmy, że zmieniają się energie tylko tych stanów, dla których (Subscript[l, 1])+(Subscript[l, 2])+J jest parzyste.

Różne nukleony (n-p)

Proton i neutron mogą utworzyć układ T=1 lub T=0. Oddziaływanie δ działa tylko na symetryczną część przestrzenej funkcji falowej, ale mamy teraz dwie możliwości: T=1, S=0 lub T=0, S=1. Dla każdej z nich siła oddziaływania może być inna, dlatego przyjmujemy:

(Subscript[V, 12])(δ)=-((Subscript[V, T=1])+(Subscript[V, T=0])) δ((OverVector[(Subscript[r, 1])]) - (OverVector[(Subscript[r, 2])])).

Wtedy:

ΔE((Subscript[j, p]),(Subscript[j, n]), J)=-(Subscript[F, 0])((Subscript[n, p])(Subscript[l, p])(Subscript[n, n])(Subscript[l, n])) ×A((Subscript[j, p])(Subscript[j, n])J),

(Subscript[F, 0])((Subscript[n, p])(Subscript[l, p])(Subscript[n, n])(Subscript[l, n]))=(1/(8π))∫(1/(r^2))(Subscript[R, (Subscript[n, p])(Subscript[l, p])]^2)(r) (Subscript[R, (Subscript[n, n])(Subscript[l, n])]^2)(r)dr,

A((Subscript[j, p])(Subscript[j, n])J)=(((2(Subscript[j, p])+1)(2(Subscript[j, n])+1))/(2J+1)) ((⟨(Subscript[j, p])(1/2),(Subscript[j, n])-(1/2),J0⟩)^2) ×
×{(Subscript[V, T=1]) ((1+(((-1))^((Subscript[l, p])+(Subscript[l, n])+J)))/2)+(Subscript[V, T=0])[((1-(((-1))^((Subscript[l, p])+(Subscript[l, n])+J)))/2)+((([(2(Subscript[j, p])+1)+(((-1))^((Subscript[j, p])+(Subscript[j, n])+J))(2(Subscript[j, n])+1)])^2)/(4J(J+1)))]}

Ogólna formuła

Powyższe wzory można zgrabnie zapisać przy pomocy jednego wyrażenia, które ma jeszcze i te przewagę, że pozwala obliczać niediagonalne elementy macierzowe (a to zaraz będzie potrzebne). Formuła ta jest wyprowadzona w książce: P.J. Brussaard, P.W.M. Glaudemans “Shell-model applications in nuclear spectroscopy” (North-Holland, 1977). Liczą oni elementy macierzowe dla oddziaływania SDI (Surface Delta Interaction), ale część kątowa jest taka sama jak dla oddziaływania δ. Aby dostać takie same wyniki jak ze wzorów powyżej, należy do wzoru BG wprowadzić dodatkowy czynnik 1/2.

Element macierzowy dla stanów dwucząstkowych sprzężonych do momentu pędu J i izospinu T (T=0, lub T=1) dany jest:

⟨(Subscript[j, a])(Subscript[j, b]),JT|-(Subscript[V, T]) δ((OverVector[(Subscript[r, 1])])-(OverVector[(Subscript[r, 2])]))|(Subscript[j, c])(Subscript[j, d]),JT⟩=-(Subscript[V, T]) (Subscript[F, r]) A((Subscript[j, a]),(Subscript[j, b]),(Subscript[j, c]),(Subscript[j, d]),J,T),

gdzie funkcję kątową A można obliczyć przy pomocy procedury:

tbmeBG[la_,ja_,lb_,jb_,lc_,jc_,ld_,jd_,J_,T_]:=Module[{val,dab,dcd},
dab=If[(la==lb)&&(ja==jb),1,0];
dcd=If[(lc==ld)&&(jc==jd),1,0];
val=(1/(2*J+1))*Sqrt[(2*ja+1)*(2*jb+1)*(2*jc+1)*(2*jd+1)/((1+dab)*(1+dcd))]*((-1)^(jb+jd+lb+ld)*ClebschGordan[{jb,-1/2},{ja,1/2},{J,0}]*ClebschGordan[{jd,-1/2},{jc,1/2},{J,0}]*(1-(-1)^(la+lb+J+T))-(1+(-1)^T)*ClebschGordan[{jb,1/2},{ja,1/2},{J,1}]*ClebschGordan[{jd,1/2},{jc,1/2},{J,1}]);
-val/2.
]

Manipulacja 1: konfiguracje dwucząstkowe

Rozważamy jądro, które składa się z parzysto-parzystego (sferycznego) rdzenia i dwóch dodatkowych nukleonów walencyjnych. Zakładamy, że rdzeń ma spin i parzystość (SuperPlus[0]), a spiny i parzystości stanów jądra wynikają ze sprzężenia obydwu nukleonów walencyjnych. Jako oddziaływanie resztkowe zakładamy siły typu δ . Energie stanów wyrażone są w jednostkach (Subscript[F, 0])(Subscript[V, 0]), gdzie (Subscript[F, 0]) jest wartością całki radialnej (nie zależy of J) a (Subscript[V, 0]) to stała sprzężenia. W przypadku różnych nukleonów, oddziaływanie może zachodzić w stanach S=0 (T=1) i S=1 (T=0), potrzebne są zatem dwie stałe sprzężenia. Względny wkład tych dwóch składowych regulujemy zmieniając stosunek stałych sprzężenia (Subscript[V, S=0])/(Subscript[V, S=1 ]).

Manipulate[
l1=Round[o1];
l2=Round[o2];
par=(-1)^(l1+l2);
If[par==1,charpar="+",charpar="-"];
If[o1>l1,j1=l1+1/2,j1=l1-1/2];
If[o2>l2,j2=l2+1/2,j2=l2-1/2];
If[same==1,
If[o1==o2,
lev=Table[{-0.5*(((2*j1+1))^2)*((ClebschGordan[{j1,1/2},{j1,-1/2},{J,0}])^2)/(2*J+1),J},{J,0,2*j1-1,2}],
lev=Table[{-(1+(-1)^(l1+l2+J))/2*(2*j1+1)*(2*j2+1)*((ClebschGordan[{j1,1/2},{j2,-1/2},{J,0}])^2)/(2*J+1),J},{J,Abs[j1-j2],j1+j2,1}]
],
lev=Table[{-(2*j1+1)*(2*j2+1)*((ClebschGordan[{j1,1/2},{j2,-1/2},{J,0}])^2)*((1+(-1)^(l1+l2+J))/2+vs1*((1-(-1)^(l1+l2+J))/2+(((2*j1+1+(-1)^(j1+j2+J)*(2*j2+1)))^2)/(4*(J+0.000001)*(J+1))))/(2*J+1),J},{J,Abs[j1-j2],j1+j2,1}]
];
imax=Length[lev];
lev1=Sort[lev];
emin=lev1[[1,1]];
emax=lev1[[imax,1]];
demin=(emax-emin)/20;
graftab={};
lastE=10;
sx=2.1;
For[i=1,i≤imax,i++,
jj=lev1[[i,2]];
If[EvenQ[jj],cb=0,cb=1];
dsx=0.2; dpx=0.05; 
If[jj≥10,dsx=0.23;dpx=0.1];
e=lev1[[i,1]];
If[Abs[e-lastE]<demin,sx= sx+dsx,sx=2.1];
lastE=e;
graftab=Append[graftab,
{{{RGBColor[cb,0,1],Thick,Line[{{0,e},{2,e}}]}},
Text[Style[jj,20],{sx,e}],
Text[Style[charpar,16],{sx+dpx,e+demin/5}]}
]
];
g0=Graphics[graftab,AxesOrigin->{0,0},PlotRange->{emin-demin,emax+demin}];
 Show[g0,Frame->{{True,False},{False,False}},FrameLabel->{" ","Energia [(Subscript[F, 0])(Subscript[V, 0])]"},FrameTicks->{{All,None},{None,None}},
BaseStyle->{Black,FontFamily->"Verdana",FontSize->20},AspectRatio->Full,PlotLabel->"",ImageSize->500],
Spacer[20],
{{same,1,Style["Nukleony:",Black,22]},{1->Style["takie same",Black,22],2->Style["różne",Black, 22]},ControlType->RadioButton},
Spacer[20],
{{o1,3.1,Style["Orbital 1:",Black, 22]},
{0.1->"(Subscript[s, 1/2])",0.9->"(Subscript[p, 1/2])",1.1->"(Subscript[p, 3/2])",1.9->"(Subscript[d, 3/2])",2.1->"(Subscript[d, 5/2])",2.9->"(Subscript[f, 5/2])",3.1->"(Subscript[f, 7/2])",3.9->"(Subscript[g, 7/2])",4.1->"(Subscript[g, 9/2])",4.9->"(Subscript[h, 9/2])",5.1->"(Subscript[h, 11/2])",5.9->"(Subscript[i, 11/2])",6.1->"(Subscript[i, 13/2])",6.9->"(Subscript[j, 13/2])",7.1->"(Subscript[j, 15/2])"}},
{{o2,3.1,Style["Orbital 2:",Black, 22]},
{0.1->"(Subscript[s, 1/2])",0.9->"(Subscript[p, 1/2])",1.1->"(Subscript[p, 3/2])",1.9->"(Subscript[d, 3/2])",2.1->"(Subscript[d, 5/2])",2.9->"(Subscript[f, 5/2])",3.1->"(Subscript[f, 7/2])",3.9->"(Subscript[g, 7/2])",4.1->"(Subscript[g, 9/2])",4.9->"(Subscript[h, 9/2])",5.1->"(Subscript[h, 11/2])",5.9->"(Subscript[i, 11/2])",6.1->"(Subscript[i, 13/2])",6.9->"(Subscript[j, 13/2])",7.1->"(Subscript[j, 15/2])"}},
{{vs1,1,Style["(Subscript[V, S = 1])/(Subscript[V, S = 0])", Hue[0,1,0.7], 22]},0,2,0.1,Appearance->"Labeled",LabelStyle->Directive[Hue[0,1,0.7],22],Enabled->If[same==2,True,False]},
TrackedSymbols->{same,o1,o2,vs1},
FrameLabel->{None, None, Style["Dwa nukleony na orbitalach 
modelu powłokowego + siły δ",Blue,26],None}
]

Manipulacja 2: dodajemy wykres energii w funkcji spinu

Manipulate[
l1=Round[o1];
l2=Round[o2];
par=(-1)^(l1+l2);
If[par==1,charpar="+",charpar="-"];
If[o1>l1,j1=l1+1/2,j1=l1-1/2];
If[o2>l2,j2=l2+1/2,j2=l2-1/2];
If[same==1,
If[o1==o2,
lev=Table[{-0.5*(((2*j1+1))^2)*((ClebschGordan[{j1,1/2},{j1,-1/2},{J,0}])^2)/(2*J+1),J},{J,0,2*j1-1,2}],
lev=Table[{-(1+(-1)^(l1+l2+J))/2*(2*j1+1)*(2*j2+1)*((ClebschGordan[{j1,1/2},{j2,-1/2},{J,0}])^2)/(2*J+1),J},{J,Abs[j1-j2],j1+j2,1}]
],
lev=Table[{-(2*j1+1)*(2*j2+1)*((ClebschGordan[{j1,1/2},{j2,-1/2},{J,0}])^2)*((1+(-1)^(l1+l2+J))/2+vs1*((1-(-1)^(l1+l2+J))/2+(((2*j1+1+(-1)^(j1+j2+J)*(2*j2+1)))^2)/(4*(J+0.000001)*(J+1))))/(2*J+1),J},{J,Abs[j1-j2],j1+j2,1}]
];
imax=Length[lev];
lev1=Sort[lev];
emin=lev1[[1,1]];
emax=lev1[[imax,1]];
demin=(emax-emin)/20;
graftab={};
glistEven={};
glistOdd={};
oddlevels=False;
lastE=10;
sx=2.1;
For[i=1,i≤imax,i++,
e=lev1[[i,1]];
jj=lev1[[i,2]];
If[EvenQ[jj],
cb=0;
glistEven=Append[glistEven,{jj,e}],
cb=1;
glistOdd=Append[glistOdd,{jj,e}];
oddlevels=True];
dsx=0.2; dpx=0.08; 
If[jj≥10,dsx=0.24;dpx=0.14];
If[Abs[e-lastE]<demin,sx= sx+dsx,sx=2.1];
lastE=e;
graftab=Append[graftab,
{{{RGBColor[cb,0,1],Thick,Line[{{0,e},{2,e}}]}},
Text[Style[jj,20],{sx,e}],
Text[Style[charpar,16],{sx+dpx,e+demin/4}]}
]
];
g0=Graphics[graftab,
AxesOrigin->{0,emax+demin},
PlotRange->{emin-demin,emax+demin},
Frame->{{True,False},{False,False}},
FrameLabel->{" ","Energia [(Subscript[F, 0])(Subscript[V, 0])]"},
FrameTicks->{{All,None},{None,None}},
LabelStyle->Directive[FontFamily->"Verdana",FontSize->20],
AspectRatio->1.1,
PlotLabel->Style["Poziomy energetyczne",20]];
If[oddlevels,
g1=ListPlot[{glistEven,glistOdd},
AxesOrigin->{0,emax+demin},
PlotRange->{emin-demin,emax+demin},
Frame->{{True,False},{False,True}},
FrameTicks->{{All,None},{None,All}},
FrameLabel->{{""," "},{"","Spin"}},
PlotStyle->{{Blue,PointSize[0.022]},{Magenta,PointSize[0.022]}},
Joined->False,Mesh->Full,
BaseStyle->{FontFamily->"Verdana",FontSize->20},
AspectRatio->1.1,
Filling->Axis
],
g1=ListPlot[glistEven,
AxesOrigin->{0,emax+demin},
PlotRange->{emin-demin,emax+demin},
Frame->{{True,False},{False,True}},
FrameTicks->{{All,None},{None,All}},
FrameLabel->{{""," "},{"","Spin"}},
PlotStyle->{Blue,PointSize[0.022]},
Joined->False,Mesh->Full,
BaseStyle->{FontFamily->"Verdana",FontSize->20},
AspectRatio->1.1
]
];
 GraphicsRow[{Show[g0],Show[g1]},
AspectRatio->1.2,
Spacings->Scaled[0.001],
ImageSize->800],
Spacer[20],
{{same,1,Style["Nukleony:",Black,22]},{1->Style["takie same",Black,22],2->Style["różne",Black, 22]},ControlType->RadioButton},
Spacer[20],
{{o1,3.1,Style["Orbital 1:",Black, 22]},
{0.1->"(Subscript[s, 1/2])",0.9->"(Subscript[p, 1/2])",1.1->"(Subscript[p, 3/2])",1.9->"(Subscript[d, 3/2])",2.1->"(Subscript[d, 5/2])",2.9->"(Subscript[f, 5/2])",3.1->"(Subscript[f, 7/2])",3.9->"(Subscript[g, 7/2])",4.1->"(Subscript[g, 9/2])",4.9->"(Subscript[h, 9/2])",5.1->"(Subscript[h, 11/2])",5.9->"(Subscript[i, 11/2])",6.1->"(Subscript[i, 13/2])",6.9->"(Subscript[j, 13/2])",7.1->"(Subscript[j, 15/2])"}},
{{o2,3.1,Style["Orbital 2:",Black, 22]},
{0.1->"(Subscript[s, 1/2])",0.9->"(Subscript[p, 1/2])",1.1->"(Subscript[p, 3/2])",1.9->"(Subscript[d, 3/2])",2.1->"(Subscript[d, 5/2])",2.9->"(Subscript[f, 5/2])",3.1->"(Subscript[f, 7/2])",3.9->"(Subscript[g, 7/2])",4.1->"(Subscript[g, 9/2])",4.9->"(Subscript[h, 9/2])",5.1->"(Subscript[h, 11/2])",5.9->"(Subscript[i, 11/2])",6.1->"(Subscript[i, 13/2])",6.9->"(Subscript[j, 13/2])",7.1->"(Subscript[j, 15/2])"}},
{{vs1,1,Style["(Subscript[V, S = 1])/(Subscript[V, S = 0])", Hue[0,1,0.7], 22]},0,2,0.1,Appearance->"Labeled",LabelStyle->Directive[Hue[0,1,0.7],22],Enabled->If[same==2,True,False]},
TrackedSymbols->{same,o1,o2,vs1},
FrameLabel->{None, None, Style["Dwa nukleony na orbitalach modelu powłokowego + siły δ",Blue,26],None}
]

Porównanie z eksperymentem

Kilka rysunków z wykładu “Fizyka jądra atomowego I” (M.P., 2009/10).

Mieszanie konfiguracji

Badaliśmy powyżej jakie stany można utworzyć z dwóch nukleonów na konkretnych orbitalach. W rzeczywistości para nukleonów może obsadzać wiele orbitali i w szczególności na wielu z nich może tworzyć stany o tym samym momencie pędu i parzystości. Wówczas będzie zachodzić zjawisko mieszania konfiguracji i stany rzeczywiste będą kombinacjami liniowymi składowych pochodzących z różnych orbitali.

Zilustrujemy to zjawisko na względnie prostym przykładzie stanów w (^18)O.

(^18)O i przestrzeń modelowa

Zakładamy, że (^18)O można opisać jako podwójnie magiczny rdzeń (^16)O plus dwa neutrony walencyjne, które mogą obsadzać orbitale (Subscript[d, 5/2]), (Subscript[s, 1/2]) i (Subscript[d, 3/2]) (tzw. powłoka sd). Energie stanów jednocząstkowych można odczytać ze znanych stanów (^17)O.

Możliwe stany dwóch neutronów na powłoce sd:

By obliczyć energie stanów i funkcje falowe z uwzględnieniem mieszania konfiguracji musimy rozwiązać problem własny dla macierzy:

(Subscript[H, ik])=(Subscript[δ, ik])(Subscript[E, k]^((0)))+⟨(Subscript[ψ, i]^((0)))|(Subscript[V, 12])(δ)|(Subscript[ψ, k]^((0)))⟩,

gdzie (Subscript[E, n]^((0)))i (Subscript[ψ, n]^((0))) to energie i funkcje falowe stanów niezaburzonych przez oddziaływanie resztkowe (lewa część rysunku powyżej). Ponieważ mieszać mogą się tylko stany o tym samym spinie i parzystości, można diagonalizować oddzielnie mniejsze macierze, dla każdego (J^π).

Stany (SuperPlus[0])

W pełnej przestrzeni powłoki sd są 3 stany (SuperPlus[0]), które mogą się mieszać.

Stany bazowe (niezaburzone) |(Subscript[j, 1])(Subscript[j, 2]);J,T=1⟩ i ich energie w MeV, to:

1) |(Subscript[d, 5/2])(Subscript[d, 5/2]); 0⟩, (Subscript[E, 1]^((0)))=0 ,         
2) |(Subscript[s, 1/2])(Subscript[s, 1/2]); 0⟩, (Subscript[E, 2]^((0)))=1.74 , 
3)|(Subscript[d, 3/2])(Subscript[d, 3/2]); 0⟩(Subscript[E, 3]^((0)))=10.16.

Obliczając elementy macierzowe oddziaływania przyjmujemy (za BG), że we wszystkich przypadkach  (Subscript[V, T]) (Subscript[F, r]) =1 MeV .

Diagonalna część macierzy H:

mE0=DiagonalMatrix[{0,1.74,10.16}];

MatrixForm[mE0]

Elementy oddziaływania:

mv11=-1.*tbmeBG[2,5/2,2,5/2,2,5/2,2,5/2,0,1]

i dalej podobnie ...

mv12=-1.*tbmeBG[2,5/2,2,5/2,0,1/2,0,1/2,0,1]

mv13=-1.*tbmeBG[2,5/2,2,5/2,2,3/2,2,3/2,0,1]

mv22=-1.*tbmeBG[0,1/2,0,1/2,0,1/2,0,1/2,0,1]

mv23=-1.*tbmeBG[0,1/2,0,1/2,2,3/2,2,3/2,0,1]

mv33=-1.*tbmeBG[2,3/2,2,3/2,2,3/2,2,3/2,0,1]

mV0={{mv11,mv12,mv13},{mv12,mv22,mv23},{mv13,mv23,mv33}};

MatrixForm[mV0]

MatrixForm[mE0+mV0]

{val0,vec0}=Eigensystem[mE0+mV0]

Stany (SuperPlus[2])

W pełnej przestrzeni powłoki sd jest 5 stanów (SuperPlus[2]), które mogą się mieszać.

Stany bazowe (niezaburzone) |(Subscript[j, 1])(Subscript[j, 2]);J,T=1⟩ i ich energie w MeV, to:

1) |(Subscript[d, 5/2])(Subscript[d, 5/2]);2⟩, (Subscript[E, 1]^((0)))=0 ,  
2) |(Subscript[d, 5/2])(Subscript[s, 1/2]);2⟩, (Subscript[E, 2]^((0)))=0.87 ,
3)|(Subscript[d, 5/2])(Subscript[d, 3/2]);2⟩, (Subscript[E, 2]^((0)))=5.08 ,
4) |(Subscript[s, 1/2])(Subscript[d, 3/2]);2⟩, (Subscript[E, 2]^((0)))=5.95 ,
5)|(Subscript[d, 3/2])(Subscript[d, 3/2]); 2⟩, (Subscript[E, 3]^((0)))=10.16 .

Obliczając elementy macierzowe oddziaływania przyjmujemy (za BG), że we wszystkich przypadkach  (Subscript[V, T]) (Subscript[F, r]) =1 MeV .

Diagonalna część macierzy H:

mE2=DiagonalMatrix[{0,0.87,5.08,5.95,10.16}];

MatrixForm[mE2]

tbmeBG[0,1/2,2,3/2,2,3/2,2,3/2,2,1]

mV2={{-0.686,0.907,-0.485,0.741,-0.524},
       {0.907, -1.2,0.641,-0.980,0.693},
       {-0.485,0.641,-0.343,0.524,-0.370},
       {0.741,-0.980,0.524,-0.8,0.566},
       {-0.524,0.693,-0.370,0.566,-0.4}};

MatrixForm[mV2]

MatrixForm[mE2+mV2]

{val2,vec2}=Eigensystem[mE2+mV2]

Stany (SuperPlus[4])

W pełnej przestrzeni powłoki sd są 2 stany (SuperPlus[4]), które mogą się mieszać.

Stany bazowe (niezaburzone) |(Subscript[j, 1])(Subscript[j, 2]);J,T=1⟩ i ich energie w MeV, to:

1) |(Subscript[d, 5/2])(Subscript[d, 5/2]);4⟩, (Subscript[E, 1]^((0)))=0 ,  
2) |(Subscript[d, 5/2])(Subscript[d, 3/2]);4⟩, (Subscript[E, 2]^((0)))=5.08 .

Obliczając elementy macierzowe oddziaływania przyjmujemy (za BG), że we wszystkich przypadkach  (Subscript[V, T]) (Subscript[F, r]) =1 MeV .

Diagonalna część macierzy H:

mE4=DiagonalMatrix[{0,5.08}];

MatrixForm[mE4]

mV4={{-0.286,-0.571},
       {-0.571, -1.143}};

MatrixForm[mV4]

MatrixForm[mE4+mV4]

{val4,vec4}=Eigensystem[mE4+mV4]

Stany (SuperPlus[0]), (SuperPlus[2]), (SuperPlus[4]) w (^18)O

Zobaczmy jak siły resztkowe typu δ zmieniają energie stanów (SuperPlus[0]), (SuperPlus[2]), (SuperPlus[4]) w (^18)O i porównajmy te najniżej leżące z doświadczeniem.

Tworzymy listy danych

niezaburzone={0,0.87,1.74,5.08,5.95,10.16};

zeroplus1={-3.0,0.74,8.16};
zeroplusFull={-4.30,1.40,8.81};

dwaplus1={-0.686,-0.33,4.74,5.15,9.76};
dwaplusFull={-1.84,0.39,4.64,5.53,9.89};

czteryplus1={-0.286,3.937};
czteryplusFull={-0.362,4.013};

gniez=Graphics[Table[{Black,Thick,Line[{{0,#},{10,#}}]}]&/@niezaburzone];
gzero1=Graphics[Table[{Red,Thick,Line[{{15,#},{25,#}}]}]&/@ zeroplus1];
gzeroF=Graphics[Table[{Red,Thick,Line[{{30,#},{40,#}}]}]&/@ zeroplusFull];
gdwa1=Graphics[Table[{Darker[Magenta],Thick,Line[{{15,#},{25,#}}]}]&/@ dwaplus1];
gdwaF=Graphics[Table[{Darker[Magenta],Thick,Line[{{30,#},{40,#}}]}]&/@ dwaplusFull];
gcztery1=Graphics[Table[{Blue,Thick,Line[{{15,#},{25,#}}]}]&/@ czteryplus1];
gczteryF=Graphics[Table[{Blue,Thick,Line[{{30,#},{40,#}}]}]&/@ czteryplusFull];

Rysunek energii przewidywanych:

Show[gniez,gzero1,gzeroF,gdwa1,gdwaF,gcztery1,gczteryF,
Frame->{{True,True},{False,False}},
FrameLabel->{None,"Energia [MeV]"},FrameTicks->{{All,All},{None,None}},
PlotRange->{{-5,43},{-6,11}},
LabelStyle->Directive[FontFamily->"Helvetica",FontSize->20],AspectRatio->0.6,PlotLabel->Style["Stany (SuperPlus[0]),(SuperPlus[2]), (SuperPlus[4]) w\!\(\*SuperscriptBox[\(\\ \), \(18\)]\)O - powłoka sd",Darker[Blue],24],
ImageSize->900,
Epilog->{
Text[Style[" bez sił δ ",Black,20],{5,-5.5}],
Text[Style[" 1 poprawka ",Black,20],{20,-5.5}],
Text[Style[" pełna diagonalizacja ",Black,20],{35,-5.5}],
Text[Style["(Subscript[d, 5/2])(Subscript[d, 5/2])",Black,17],{-2.2,niezaburzone[[1]]}],
Text[Style["(Subscript[d, 5/2])(Subscript[s, 1/2])",Black,17],{-2.2,niezaburzone[[2]]}],
Text[Style["(Subscript[s, 1/2])(Subscript[s, 1/2])",Black,17],{-2.2,niezaburzone[[3]]}],
Text[Style["(Subscript[d, 5/2])(Subscript[d, 3/2])",Black,17],{-2.2,niezaburzone[[4]]}],
Text[Style["(Subscript[s, 1/2])(Subscript[d, 3/2])",Black,17],{-2.2,niezaburzone[[5]]}],
Text[Style["(Subscript[d, 3/2])(Subscript[d, 3/2])",Black,17],{-2.2,niezaburzone[[6]]}],
{Thin,Black, Dashed, Line[{{10,niezaburzone[[1]]},{15,zeroplus1[[1]]}}]},
{Thin,Black, Dashed, Line[{{10,niezaburzone[[1]]},{15,dwaplus1[[1]]}}]},
{Thin,Black, Dashed, Line[{{10,niezaburzone[[1]]},{15,czteryplus1[[1]]}}]},
{Thin,Black, Dashed, Line[{{10,niezaburzone[[2]]},{15,dwaplus1[[2]]}}]},
{Thin,Black, Dashed, Line[{{10,niezaburzone[[3]]},{15,zeroplus1[[2]]}}]},
{Thin,Black, Dashed, Line[{{10,niezaburzone[[4]]},{15,dwaplus1[[3]]}}]},
{Thin,Black, Dashed, Line[{{10,niezaburzone[[4]]},{15,czteryplus1[[2]]}}]},
{Thin,Black, Dashed, Line[{{10,niezaburzone[[5]]},{15,dwaplus1[[4]]}}]},
{Thin,Black, Dashed, Line[{{10,niezaburzone[[6]]},{15,dwaplus1[[5]]}}]},
{Thin,Black, Dashed, Line[{{10,niezaburzone[[6]]},{15,zeroplus1[[3]]}}]},
{Thin,Black, Dashed, Line[{{25,zeroplus1[[1]]},{30,zeroplusFull[[1]]}}]},
{Thin,Black, Dashed, Line[{{25,zeroplus1[[2]]},{30,zeroplusFull[[2]]}}]},
{Thin,Black, Dashed, Line[{{25,zeroplus1[[3]]},{30,zeroplusFull[[3]]}}]},
{Thin,Black, Dashed, Line[{{25,dwaplus1[[1]]},{30,dwaplusFull[[1]]}}]},
{Thin,Black, Dashed, Line[{{25,dwaplus1[[2]]},{30,dwaplusFull[[2]]}}]},
{Thin,Black, Dashed, Line[{{25,dwaplus1[[3]]},{30,dwaplusFull[[3]]}}]},
{Thin,Black, Dashed, Line[{{25,dwaplus1[[4]]},{30,dwaplusFull[[4]]}}]},
{Thin,Black, Dashed, Line[{{25,dwaplus1[[5]]},{30,dwaplusFull[[5]]}}]},
{Thin,Black, Dashed, Line[{{25,czteryplus1[[1]]},{30,czteryplusFull[[1]]}}]},
{Thin,Black, Dashed, Line[{{25,czteryplus1[[2]]},{30,czteryplusFull[[2]]}}]},
Text[Style["(SuperPlus[0])",Red,17],{41,zeroplusFull[[1]]}],
Text[Style["(SuperPlus[0])",Red,17],{41,zeroplusFull[[2]]}],
Text[Style["(SuperPlus[0])",Red,17],{41,zeroplusFull[[3]]}],
Text[Style["(SuperPlus[2])",Darker[Magenta],17],{41,dwaplusFull[[1]]}],
Text[Style["(SuperPlus[2])",Darker[Magenta],17],{41,dwaplusFull[[2]]}],
Text[Style["(SuperPlus[2])",Darker[Magenta],17],{41,dwaplusFull[[3]]}],
Text[Style["(SuperPlus[2])",Darker[Magenta],17],{41,dwaplusFull[[4]]}],
Text[Style["(SuperPlus[2])",Darker[Magenta],17],{41,dwaplusFull[[5]]}]
}
]

Dane doświadczalne

eksp = {0, 1.982, 3.555};

Porównanie przewidywań z doświadczeniem

Show[
Graphics[{Red,Thick,Line[{{0,0},{10,0}}]}],
Graphics[{Darker[Magenta],Thick,Line[{{0,dwaplus1[[1]]-zeroplus1[[1]]},{10,dwaplus1[[1]]-zeroplus1[[1]]}}]}],
Graphics[{Blue,Thick,Line[{{0,czteryplus1[[1]]-zeroplus1[[1]]},{10,czteryplus1[[1]]-zeroplus1[[1]]}}]}],
Graphics[{Red,Thick,Line[{{15,0},{25,0}}]}],
Graphics[{Darker[Magenta],Thick,Line[{{15,dwaplusFull[[1]]-zeroplusFull[[1]]},{25,dwaplusFull[[1]]-zeroplusFull[[1]]}}]}],
Graphics[{Blue,Thick,Line[{{15,czteryplusFull[[1]]-zeroplusFull[[1]]},{25,czteryplusFull[[1]]-zeroplusFull[[1]]}}]}],
Graphics[{Black,Thick,Line[{{30,eksp[[1]]},{40,eksp[[1]]}}]}],
Graphics[{Black,Thick,Line[{{30,eksp[[2]]},{40,eksp[[2]]}}]}],
Graphics[{Black,Thick,Line[{{30,eksp[[3]]},{40,eksp[[3]]}}]}],
Frame->{{True,True},{False,False}},
FrameLabel->{None,"Energia [MeV]"},FrameTicks->{{All,All},{None,None}},
PlotRange->{{-2,43},{-0.7,4.6}},
LabelStyle->Directive[FontFamily->"Helvetica",FontSize->20],AspectRatio->0.6,PlotLabel->Style["Pierwsze stany (SuperPlus[0]),(SuperPlus[2]),(SuperPlus[4]) w\!\(\*SuperscriptBox[\(\\ \), \(18\)]\)O",Darker[Blue],24],
ImageSize->900,
Epilog->{
Text[Style[" 1 poprawka ",Black,22],{5,-0.5}],
Text[Style[" pełna diagonalizacja ",Black,22],{20,-0.5}],
Text[Style[" eksperyment ",Black,22],{35,-0.5}],
Text[Style["(SuperPlus[0])",Black,20],{11,0}],
Text[Style["(SuperPlus[2])",Black,20],{11,dwaplus1[[1]]-zeroplus1[[1]]}],
Text[Style["(SuperPlus[4])",Black,20],{11,czteryplus1[[1]]-zeroplus1[[1]]}],
Text[Style["(SuperPlus[0])",Black,20],{26,0}],
Text[Style["(SuperPlus[2])",Black,20],{26,dwaplusFull[[1]]-zeroplusFull[[1]]}],
Text[Style["(SuperPlus[4])",Black,20],{26,czteryplusFull[[1]]-zeroplusFull[[1]]}],
Text[Style["(SuperPlus[0])",Black,20],{41,eksp[[1]]}],
Text[Style["(SuperPlus[2])",Black,20],{41,eksp[[2]]}],
Text[Style["(SuperPlus[4])",Black,20],{41,eksp[[3]]}],
}]

Mieszanie wielu stanów

Zjawisko mieszania stanów przez oddziaływania zaburzające, takie jak resztkowe, występuje nader często w fizyce jądrowej. Na koniec zbadamy pewien szczególny i pouczający przypadek, w którym wszystkie elementy macierzowe oddziaływania zaburzającego mają tę samą wartość.

Macierz, którą chcemy diagonalizować ma więc postać:

[H]=(({{(Subscript[E, 1]^((0))), 0, ⃛, 0}, {0, (Subscript[E, 2]^((0))), ⃛, 0}, {⋮, ⋮, ⋱, ⋮}, {0, 0, ⃛, (Subscript[E, n]^((0)))}}))-V (({{1, 1, ⃛, 1}, {1, 1, ⃛, 1}, {⋮, ⋮, ⋱, ⋮}, {1, 1, ⃛, 1}}))

Rozważymy model takiej sytuacji, w którym energie niezaburzone są równoodległe, jak w oscylatorze harmonicznym.

Manipulacja 4: model mieszania wielu stanów

Stany wyjściowe (o liczbie od dwóch do siedmiu), bez oddziaływań szczątkowych mają energie równo odległe od siebie, jak stany oscylatora harmonicznego. Energetyczna odległość między nimi wynosi ΔE. Zakładamy, że wartości elementów macierzowych oddziaływania resztkowego są takie same dla każdej pary stanów (diagonalnych i pozadiagonalnych) i wynoszą - V. Wartość V wyznacza skalę energii. Stosunek ΔE/V może się zmieniać od 0 do 5.

Manipulate[
val0=r Table[i,{i,0,n-1}];
md=DiagonalMatrix[val0];
mv=Table[1,{i,n},{j,n}];
g0=Graphics[Table[{{Blue,Thick,Line[{{0.5,#},{2.5,#}}]}}]&/@val0,AxesOrigin->{0,0},AxesLabel->{None,"Energia [V]"}];
{val,vec}=Eigensystem[md - mv];
gmix= Graphics[Table[{{Red,Thick,Line[{{3,#},{5,#}}]}}]&/@val];
 Show[g0,gmix,Frame->{{True,True},{False,False}},FrameLabel->{None,"Energia [V]"},FrameTicks->{{All,All},{None,None}},
BaseStyle->{Black,FontFamily->"Verdana",FontSize->20},
AspectRatio->Full,PlotLabel->Style["nie zmieszane",Black,20]Style["        zmieszane",Hue[0,1,0.7],20],
ImageSize->500],
Spacer[20],
{{n,2,Style["Liczba stanów",Black,22]},{2->Style["2",20],3->Style["3",20],4->Style["4",20],5->Style["5",20],6->Style["6",20],7->Style["7",20]}},{{r,0,Style["ΔE/V",Hue[0,1,0.7],22]},0,5, Appearance->"Labeled", LabelStyle->Directive[Hue[0,1,0.7], 22]},
FrameLabel->{None, None, Style["Mieszanie wielu stanów",Blue,26],None}
]